Код

Функция РазобратьВСписок(Стр, Узел="$") Экспорт

	итJSON = глБДSQLite.НовыйЗапрос().ВыполнитьЗапрос(
		"SELECT
		| key as Ключ, atom as Значение, type as Тип, id as [ИД $Число.10.0], parent as [ИДРодителя $Число.10.0]
		|FROM json_tree('" + Стр + "', '" + Узел + "')", СоздатьОбъект("ИндексированнаяТаблица"));

	Если итJSON.КоличествоСтрок() = 0 Тогда
		Возврат СоздатьОбъект("СписокЗначений");
	КонецЕсли;

	итОбъектов = СоздатьОбъект("ИндексированнаяТаблица");
	итОбъектов.НоваяКолонка("ИД");
	итОбъектов.НоваяКолонка("Объект");

	ИндексИДОбъекта = итОбъектов.ДобавитьИндекс("ИД", "ИД", 1);

	ТекИДОбъекта = итJSON.ПолучитьЗначение(1, "ИД");
	ТекОбъект = СоздатьОбъект("СписокЗначений");

	итОбъектов.НоваяСтрока();
	итОбъектов.ИД = ТекИДОбъекта;
	итОбъектов.Объект = ТекОбъект;

	итJSON.ВыбратьСтроки();
	Пока итJSON.ПолучитьСтроку() = 1 Цикл
		ТекТип = итJSON.Тип;
		Если Найти("text,integer,true,false,null", ТекТип) > 0 Тогда
			ТекЗначение = итJSON.Значение;

		ИначеЕсли Найти("object,array", ТекТип) > 0 Тогда
			Если итJSON.ИД = ТекИДОбъекта Тогда
				Продолжить; //это уже обработано еще до цикла
			КонецЕсли;

			ТекЗначение = СоздатьОбъект("СписокЗначений");

			итОбъектов.НоваяСтрока();
			итОбъектов.ИД = итJSON.ИД;
			итОбъектов.Объект = ТекЗначение;

		ИначеЕсли ТекТип = "real" Тогда
			ТекЗначение = Окр(итJSON.Значение, 8); //чтобы не было значений типа 1.19999999999999

		Иначе
			глВывестиМногострочноеСообщение("РазобратьВСписок2: Неизвестный тип значения - " + ТекТип + ". Значение " + итJSON.Значение);
			Продолжить;
		КонецЕсли;

		Если ТекИДОбъекта <> итJSON.ИДРодителя Тогда
			ТекИДОбъекта = итJSON.ИДРодителя;
			Если итОбъектов.НайтиСтроку(ИндексИДОбъекта, ТекИДОбъекта, 0, 1) = 0 Тогда
				глВывестиМногострочноеСообщение("РазобратьВСписок2: Какая-то ошибка - не найден объект, который уже должен был быть загружен - " + ТекИДОбъекта);
				ТекИДОбъекта = -1;
				Продолжить;
			КонецЕсли;

			ТекОбъект = итОбъектов.Объект;
		КонецЕсли;

		ТекОбъект.ДобавитьЗначение(ТекЗначение, Строка(итJSON.Ключ));
	КонецЦикла;

	Возврат итОбъектов.ПолучитьЗначение(1, "Объект");

КонецФункции //РазобратьВСписок