Код

Процедура Инициализация(Знач пКонт = 0) Экспорт
	Если пКонт <> 0 Тогда // если контекст не равен "0" то перехватываем ГК
		КонтекстПерехваченнойФормы=пКонт;
		Права.ОбъектМетаданных = КонтекстПерехваченнойФормы;
		Перехватчик.ПерехватитьСобытияГК(КонтекстПерехваченнойФормы,Контекст);
	Иначе  // а иначе перехватываем ГМ
		//Сообщить("Перехвачен ГМ");
		Настройки = СоздатьОбъект("УправлениеНастройками");
		Настройки.Включить("ПерехватитьСобытияГК");
		СтарыйПерехватчикСобытий = Перехватчик.ПолучитьПерехватчикСобытийГлобальногоМодуля();
		Перехватчик.СнятьПерехватСобытийГлобальногоМодуля();
		Перехватчик.ПерехватитьСобытияГлобальногоМодуля(Сам());

		Перехватчик.ПодключитьСобытие_НеобработаннаяОшибка();
		Перехватчик.ПодключитьСобытие_ЗаписьСобытияЖурналаРегистрации();
		;

		// ФормаРасш и Права могут быть не инициализированы в Конструкторе. Причину см. в самом Конструкторе
		Если ПустоеЗначение(ФормаРасш) = 1 Тогда
			ФормаРасш=СоздатьОбъектВК("FormEx.dll", "РасширениеФормы");
		КонецЕсли;
		Если ПустоеЗначение(Права) = 1 Тогда
			МетаКлассы = СоздатьОбъект("MetaInfoClasses");
			сзКлассов = МетаКлассы.ПолучитьВсеИменаКлассов();
			Если сзКлассов.НайтиЗначение("ПраваНаОбъектыМетаданныхРасш") <> 0 Тогда
				Права = СоздатьОбъект("ПраваНаОбъектыМетаданныхРасш");
			Иначе
				Права = СоздатьОбъект("ПраваНаОбъектыМетаданных");
			КонецЕсли;  
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

//Создаем экземпляр самого себя и этим экземпляром перехватываем уже не ГМ а ГК
Функция СоздатьЭкземплярСамогоСебя(Знач КонтФормы)
	Если (ФормаРасш.ТипОбъекта() = "Отчет") Или (ФормаРасш.ТипОбъекта() = "Обработка") ИЛИ (ФормаРасш.ТипОбъекта() = "ВнешнийОтчет") Тогда
		НазваниеКлассаПерехватчика = "ПерехватчикСобытийОтчет";
	ИначеЕсли ФормаРасш.ТипОбъекта() = "Справочник" Тогда
		НазваниеКлассаПерехватчика = "ПерехватчикСобытийСпр";
	Иначе
		НазваниеКлассаПерехватчика = ТипЗначенияСтр(Сам());
	КонецЕсли;
	ПерехватчикСобытий = СоздатьОбъект(НазваниеКлассаПерехватчика);
	ПерехватчикСобытий.Инициализация(КонтФормы);
	Возврат 1;
КонецФункции

Функция СобытиеГМ_ПриОткрытии(КонтФормы, ФлагЧтенияНастройки) Экспорт
	//Сообщить("СобытиеГМ_ПриОткрытии " + Строка(КонтФормы));
	Если ПустоеЗначение(КонтФормы) = 0 Тогда
		ПерехватчикСобытий = Перехватчик.ПолучитьПерехватчикСобытийГК(КонтФормы);
		Если ПустоеЗначение(ПерехватчикСобытий) = 1 Тогда
			Возврат СоздатьЭкземплярСамогоСебя(КонтФормы);
		КонецЕсли;
	КонецЕсли;
	Возврат 1;
КонецФункции