Код

Функция ПолучитьШаблонПерехватаСобытий(СсылкаКонтекст)

	ТипКонтекста	= гСервис.ПолныйТипКонтекста(СсылкаКонтекст);
	Если гКэшНаличияДелегатов.НайтиСтроку("ОсновнойИндекс", ТипКонтекста, 0, 1) = 0 Тогда

		---------------
		// Построим шаблон
		ШаблонМетодов	= "";
		гТаблицаШаблонов.ВыбратьСтроки();
		Пока гТаблицаШаблонов.ПолучитьСтроку() = 1 Цикл

			ИдентификаторСобытия		= гТаблицаШаблонов.Ссылка.ПолучитьИдентификаторСобытия();
			ПубликоватьСобытияДоПосле	= гТаблицаШаблонов.Ссылка.ПубликоватьСобытияДоПосле();
			ЕстьДелегатыСобытия			= 0;
			Если ПубликоватьСобытияДоПосле = 1 Тогда
				ЕстьДелегатыСобытия	= Макс(гМенеджерСобытий.ЕстьДелегатыСобытия("ДоСобытия" + ИдентификаторСобытия, СсылкаКонтекст), гМенеджерСобытий.ЕстьДелегатыСобытия("ПослеСобытия"
 + ИдентификаторСобытия, СсылкаКонтекст));
			Иначе
				ЕстьДелегатыСобытия	= гМенеджерСобытий.ЕстьДелегатыСобытия(ИдентификаторСобытия, СсылкаКонтекст);
			КонецЕсли;
			Если ЕстьДелегатыСобытия = 0 Тогда
				Продолжить;
			КонецЕсли;
			Если гТаблицаШаблонов.Ссылка.ПринадлежитКонтексту(ТипКонтекста) = 0 Тогда
				Продолжить;
			КонецЕсли;

			КоличествоПараметров		= гТаблицаШаблонов.Ссылка.ПолучитьКоличествоПараметров();
			СтрокаПараметров			= "";
			Для НомерПараметра = 1 По КоличествоПараметров Цикл
				СтрокаПараметров	= СтрокаПараметров + ",Параметр" + НомерПараметра;
			КонецЦикла;

			ШаблонМетодов	= ШаблонМетодов + "
			| // Перехват события " + ИдентификаторСобытия + "
			| Функция " + ИдентификаторСобытия + "(" + Прав(СтрокаПараметров, СтрДлина(СтрокаПараметров) - 1) + ") Экспорт
			|	Событие			= СоздатьОбъект(""Общие.Событие"");
			|	Результат		= 1;
			|";

			Если ПубликоватьСобытияДоПосле = 1 Тогда
				ШаблонМетодов	= ШаблонМетодов + "
				|	Результат	= Событие.Опубликовать(""ДоСобытия" + ИдентификаторСобытия + """, гСсылкаКонтекст" + СтрокаПараметров + ");
				|";
			Иначе
				ШаблонМетодов	= ШаблонМетодов + "
				|	Результат	= Событие.Опубликовать(""" + ИдентификаторСобытия + """, гСсылкаКонтекст" + СтрокаПараметров + ");
				|";
			КонецЕсли;
			ШаблонМетодов	= ШаблонМетодов + "
			|	Если Результат = 1 Тогда
			|		Результат	= гПерехватчик.ВыполнитьОригинальноеСобытиеГК(гСсылкаКонтекст, """ + ИдентификаторСобытия + """" + СтрокаПараметров + ");
			|	КонецЕсли;
			|";
			Если ПубликоватьСобытияДоПосле = 1 Тогда
				ШаблонМетодов	= ШаблонМетодов + "
				| Если Результат = 1 Тогда
				|	Результат	= Событие.Опубликовать(""ПослеСобытия" + ИдентификаторСобытия + """, гСсылкаКонтекст" + СтрокаПараметров + ");
				| КонецЕсли;
				|";
			КонецЕсли;
			ШаблонМетодов	= ШаблонМетодов + "
			| 	Возврат Результат;
			| КонецФункции
			|";
		КонецЦикла;

		Если ПустаяСтрока(ШаблонМетодов) = 0 Тогда

			ШаблонМетодов	= "
			|
			| Перем гСсылкаКонтекст, гПерехватчик;
			|
			| Процедура УстановитьПараметры(СсылкаКонтекст) Экспорт
			|	гСсылкаКонтекст		= СсылкаКонтекст;
			|	гПерехватчик		= СоздатьОбъект(""Перехватчик"");
			| КонецПроцедуры
			|
			|" + ШаблонМетодов;

		КонецЕсли;

		гКэшНаличияДелегатов.НоваяСтрока();
		гКэшНаличияДелегатов.Индекс	= ТипКонтекста;
		гКэшНаличияДелегатов.Шаблон	= ШаблонМетодов;

	КонецЕсли;

	Возврат гКэшНаличияДелегатов.Шаблон;
КонецФункции // ПолучитьШаблонПерехватаСобытий()

...


// ОбработатьСобытие_СозданиеКонтекста(Параметры)
//
// Параметры:
//  Параметры
//
// Возвращаемое значение:
//  Нет
//
// Описание:
//  ТекстОписания
//
Функция ОбработатьСобытие_СозданиеКонтекста(Параметры)

	Результат		= 1;
	СсылкаКонтекст	= Параметры.ПолучитьЗначение(1);
	ТекстМодуля		= ПолучитьШаблонПерехватаСобытий(СсылкаКонтекст);

	Если ПустаяСтрока(ТекстМодуля) = 1 Тогда
		Возврат Результат;
	КонецЕсли;

	Делегат		= СоздатьОбъект("Общие.Абстрактный.Модуль");
	Делегат.РазрешитьВложенныйВызовМетодов();
	Делегат.НазначитьКонтекст(СсылкаКонтекст);
	Делегат.УстановитьМодуль(ТекстМодуля);
	Если Делегат.КомпилироватьМодуль() = 0 Тогда
		Сообщить("Не удалось создать перехватчик событий " + ТипЗначенияСтр(_this()));
	КонецЕсли;
	Делегат.ВыполнитьМодуль();
	Делегат.ПрисоединитьТекущийМодуль();
	Делегат.УстановитьПараметры(СсылкаКонтекст);
	гПерехватчик.ПерехватитьСобытияГК(СсылкаКонтекст, Делегат);

	Возврат Результат;
КонецФункции // ОбработатьСобытие_СозданиеКонтекста()